+Show TOC
×Hide TOC

NumberUtil

Kind of class:	class
Inherits from:	none
Version:	06/28/07
Author:	Aaron Clinger, David Nelson
Classpath:	org.casaframework.util.NumberUtil
File last modified:	Sunday, 19 August 2007, 13:43:36

► View source

▼ Hide source

/*
    CASA Framework for ActionScript 2.0
    Copyright (C) 2007  CASA Framework
    http://casaframework.org
    
    This library is free software; you can redistribute it and/or
    modify it under the terms of the GNU Lesser General Public
    License as published by the Free Software Foundation; either
    version 2.1 of the License, or (at your option) any later version.
    
    This library is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
    Lesser General Public License for more details.
    
    You should have received a copy of the GNU Lesser General Public
    License along with this library; if not, write to the Free Software
    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
*/

/**
    @author Aaron Clinger
    @author David Nelson
    @version 06/28/07
*/

class org.casaframework.util.NumberUtil {
    
    /**
        Evaluates <code>val1</code> and <code>val2</code> and returns the smaller value. Unlike <code>Math.min</code> this method will return the defined value if the other value is <code>undefined</code>.
        
        @param val1: A number or expression to compare.
        @param val2: A number or expression to compare.
        @return Returns the smallest value, or the value out of the two that is defined.
    */
    public static function min(val1:Number, val2:Number):Number {
        if (val1 == undefined || val2 == undefined)
            return (val2 == undefined) ? val1 : val2;
        
        return Math.min(val1, val2);
    }
    
    /**
        Evaluates <code>val1</code> and <code>val2</code> and returns the larger value. Unlike <code>Math.max</code> this method will return the defined value if the other value is <code>undefined</code>.
        
        @param val1: A number or expression to compare.
        @param val2: A number or expression to compare.
        @return Returns the largest value, or the value out of the two that is defined.
    */
    public static function max(val1:Number, val2:Number):Number {
        if (val1 == undefined || val2 == undefined) 
            return (val2 == undefined) ? val1 : val2;
        
        return Math.max(val1, val2);
    }
    
    /**
        Creates a random integer within the defined range.
        
        @param min: The minimum number the random integer can be.
        @param min: The maximum number the random integer can be.
        @return Returns a random integer within the range.
    */
    public static function randomInteger(min:Number, max:Number):Number {
        return min + Math.floor(Math.random() * (max + 1 - min));
    }
    
    /**
        Determines if the number is even.
        
        @param num: A number to determine if it is divisible by <code>2</code>.
        @return Returns <code>true</code> if the number is even; otherwise <code>false</code>.
    */
    public static function isEven(num:Number):Boolean {
        return (num & 1) == 0;
    }
    
    /**
        Determines if the number is odd.
        
        @param num: A number to determine if it is not divisible by <code>2</code>.
        @return Returns <code>true</code> if the number is odd; otherwise <code>false</code>.
    */
    public static function isOdd(num:Number):Boolean {
        return !NumberUtil.isEven(num);
    }
    
    /**
        Determines if the number is an integer.
        
        @param num: A number to determine if it contains no decimal values.
        @return Returns <code>true</code> if the number is an integer; otherwise <code>false</code>.
    */
    public static function isInteger(num:Number):Boolean {
        return (num % 1) == 0;
    }
    
    /**
        Determines if the number is prime.
        
        @param num: A number to determine if it is only divisible by 1 and itself.
        @return Returns <code>true</code> if the number is prime; otherwise <code>false</code>.
    */
    public static function isPrime(num:Number):Boolean {
        if (num == 1)
            return true;
        
        if (NumberUtil.isEven(num))
            return false;
        
        var s:Number = Math.sqrt(num);
        for (var i:Number = 3; i <= s; i++)
            if (num % i == 0)
                return false;
        
        return true;
    }
    
    /**
        Rounds a number's decimal value to a specific place.
        
        @param num: The number to round.
        @param place: The decimal place to round.
        @return Returns the value rounded to the defined place. 
        @example
            <code>
                trace(NumberUtil.roundToPlace(3.14159, 2)); // Traces 3.14
                trace(NumberUtil.roundToPlace(3.14159, 3)); // Traces 3.142
            </code>
    */
    public static function roundDecimalToPlace(num:Number, place:Number):Number {
        var p:Number = Math.pow(10, Math.round(place));
        
        return Math.round(num * p) / p;
    }
    
    /**
        Determines if the value is included within a range.
        
        @param num: Number to determine if it's included in the range.
        @param startValue: First value of the range.
        @param endValue: Second value of the range.
        @return Returns <code>true</code> if the number falls within the range; otherwise <code>false</code>.
    */
    public static function isBetween(num:Number, startValue:Number, endValue:Number):Boolean {
        return !(num < Math.min(startValue, endValue) || num > Math.max(startValue, endValue));
    }
    
    /**
        Determines if value falls within a range; if not it is snapped to the nearest range value.
        
        @param num: Number to determine if it's included in the range.
        @param startValue: First value of the range.
        @param endValue: Second value of the range.
        @return Returns either the number as passed, or its value once snapped to nearest range value.
    */
    public static function makeBetween(num:Number, startValue:Number, endValue:Number):Number {
        return Math.min(Math.max(num, Math.min(startValue, endValue)), Math.max(startValue, endValue));
    }
    
    /**
        Creates evenly spaced numerical increments between two numbers.
        
        @param begin: The starting value.
        @param end: The ending value.
        @param steps: The number of increments between the starting and ending values.
        @return Returns an Array comprised of the increments between the two values.
        @example
            <code>
                trace(NumberUtil.createStepsBetween(0, 5, 4)); // Traces 1,2,3,4
                trace(NumberUtil.createStepsBetween(1, 3, 3)); // Traces 1.5,2,2.5
            </code>
    */
    public static function createStepsBetween(begin:Number, end:Number, steps:Number): /*Number*/ Array {
        steps++;
        
        var i:Number = 0;
        var stepsBetween: /*Number*/ Array = new Array();
        var increment:Number = (end - begin) / steps;
        
        while (++i < steps)
            stepsBetween.push((i * increment) + begin);
        
        return stepsBetween;
    }
    
    /**
        Formats a number.
        
        @param numberToFormat: The number you wish to format.
        @param minLength: The minimum length of the number.
        @param thouDelim: <strong>[optional]</strong> The character used to seperate thousands; defaults to none.
        @param fillChar: <strong>[optional]</strong> The leading character used to make the number the minimum length; defaults to <code>0</code>.
        @return Returns the formated number as a String.
        @example
            <code>
                trace(NumberUtil.format(1234567, 8, ",")); // Traces 01,234,567
            </code>
    */
    public static function format(numberToFormat:Number, minLength:Number, thouDelim:String, fillChar:String):String {
        var num:String = numberToFormat.toString();
        var len:Number = num.length;
        
        if (thouDelim != undefined) {
            var numSplit:Array = num.split('');
            var counter:Number = 3;
            var i:Number       = numSplit.length;
            
            while (--i > 0) {
                counter--;
                if (counter == 0) {
                    counter = 3;
                    numSplit.splice(i, 0, thouDelim);
                }
            }
            
            num = numSplit.join('');
        }
        
        if (minLength != undefined) {
            if (len < minLength) {
                minLength -= len;
                
                var addChar:String = (fillChar == undefined) ? '0' : fillChar;
                
                while (minLength--)
                    num = addChar + num;
            }
        }
        
        return num;
    }
    
    /**
        Finds the English ordinal suffix for the number given.
        
        @param num: Number to find the ordinal suffix of.
        @return Returns the suffix for the number, 2 characters.
        @example
            <code>
                trace(32 + NumberUtil.getOrdinalSuffix(32)); // Traces 32nd
            </code>
    */
    public static function getOrdinalSuffix(num:Number):String {
        if (num >= 10 && num <= 20)
            return 'th';
            
        switch (num % 10) {
            case 0 :
            case 4 :
            case 5 :
            case 6 :
            case 7 :
            case 8 :
            case 9 :
                return 'th';
            case 3 :
                return 'rd';
            case 2 :
                return 'nd';
            case 1 :
                return 'st';
        }
    }
    
    /**
        Adds a leading zero for numbers less than ten.
        
        @param num: Number to add leading zero.
        @return Number as a String; if the number was less than ten the number will have a leading zero.
    */
    public static function addLeadingZero(num:Number):String {
        return (num < 10) ? '0' + num : num.toString();
    }
    
    private function NumberUtil() {} // Prevents instance creation
}

Summary

Class methods

min
max
randomInteger
isEven
isOdd
isInteger
isPrime
roundDecimalToPlace
isBetween
makeBetween
createStepsBetween
format
getOrdinalSuffix
addLeadingZero

Class methods

addLeadingZero

static function addLeadingZero (num:Number) : String

10以下の数字の先頭に0を追加します。

Parameters:

num:

０を追加したい数字

Returns:

指定した数字が１０未満の場合、先頭に０が付いてString型で返ってきます（10未満では無い場合もStringに変換されます）

createStepsBetween

static function createStepsBetween (begin:Number, end:Number, steps:Number) : Array

指定した2つの数字間で均等に割られた区切りの数字を返します。

Parameters:

begin:

開始値

end :

終了地

steps:

ステップ数

Returns:

指定した2つの数字間をを均等に割られた区切りの数字をArray型で返します

Example:

trace(NumberUtil.createStepsBetween(0, 5, 4)); // Traces 1,2,3,4
trace(NumberUtil.createStepsBetween(1, 3, 3)); // Traces 1.5,2,2.5

format

static function format (numberToFormat:Number, minLength:Number, thouDelim:String, fillChar:String) : String

数字を整形します。

Parameters:

numberToFormat:

整形したい数字

minLength :

最小桁数

thouDelim :

[オプション] 区切り文字（いわゆるカンマのところに入る文字）、デフォルトは区切り文字無し

fillChar :

[オプション] minLengthで指定した桁数より少ない場合に先頭に入る文字、デフォルトは"0"

Returns:

整形された値がString型で返ってきます。

Example:

trace(NumberUtil.format(1234567, 8, ",")); // Traces 01,234,567

getOrdinalSuffix

static function getOrdinalSuffix (num:Number) : String

序数の接尾語（いわゆる1st, 2nd, 3rdとかの後ろ2文字のアルファベット）を取得する

Parameters:

num:

序数の接尾語を取得する値

Returns:

序数の接尾語が返ってきます（数字は返ってこずに2文字のStringのみ）

Example:

trace(32 + NumberUtil.getOrdinalSuffix(32)); // Traces 32nd

isBetween

static function isBetween (num:Number, startValue:Number, endValue:Number) : Boolean

指定した値が、指定した範囲内かどうかを調べる

Parameters:

num :

範囲内にあるかどうかを調べたい値

startValue:

調べる範囲の1つ目の値

endValue :

調べる範囲の２つ目の値

Returns:

指定した値がstartValue以上、endValue以下（もしくはその逆）の場合はtrue、それ以外はfalseが返ってくる。

isEven

static function isEven (num:Number) : Boolean

偶数かどうかを調べる

Parameters:

num:

調べる値

Returns:

偶数ならtrue、それ以外ならfalseが返ってくる

isInteger

static function isInteger (num:Number) : Boolean

整数かどうかを調べる

Parameters:

num:

調べる値

Returns:

指定した値が整数の場合はtrue、それ以外の場合はfalseを返します。

isOdd

static function isOdd (num:Number) : Boolean

奇数かどうかを調べる

Parameters:

num:

調べる値

Returns:

指定した値が奇数の場合はtrue、それ以外の場合はfalseを返します。

isPrime

static function isPrime (num:Number) : Boolean

素数かどうかを調べます。

Parameters:

num:

調べる値

Returns:

指定した値が素数の場合はtrue、それ以外の場合はfalseを返します。

makeBetween

static function makeBetween (num:Number, startValue:Number, endValue:Number) : Number

指定した値を指定した範囲内に丸める（日本語として怪しい）

Parameters:

num :

範囲に含まれているかどうかを調べる値

startValue:

指定する範囲の1つ目の値

endValue :

指定する範囲の2つ目の値

Returns:

指定した値が範囲内の場合はそのままnumを返します。範囲外の場合は、指定した値に一番近い範囲内の値を返します。

max

static function max (val1:Number, val2:Number) : Number

指定した2つの値を比較して大きい値を返します。Math.maxとの違いundefined等、数値以外が含まれていても正しい結果を返します。

Parameters:

val1:

比較する値

val2:

比較する値

Returns:

2つの値を比較して大きい方を返します。

min

static function min (val1:Number, val2:Number) : Number

指定した2つの値を比較しての小さい値を返します。Math.maxとの違いundefined等、数値以外が含まれていても正しい結果を返します。

Parameters:

val1:

比較する値

val2:

比較する値

Returns:

2つの値を比較して小さい方を返します。

randomInteger

static function randomInteger (min:Number, max:Number) : Number

指定した範囲内でランダムな整数を生成します

Parameters:

min:

ランダムな整数を作成する際の最小値

min:

ランダムな整数を作成する際の最大値

Returns:

指定した範囲内のランダムな整数を返します。

roundDecimalToPlace

static function roundDecimalToPlace (num:Number, place:Number) : Number

小数点以下の桁を指定した桁数で四捨五入します。

Parameters:

num :

四捨五入する値

place:

小数点以下の桁数

Returns:

指定した値を指定した桁数で四捨五入された値を返します。

Example:

trace(NumberUtil.roundDecimalToPlace(3.14159, 2)); // Traces 3.14
trace(NumberUtil.roundDecimalToPlace(3.14159, 3)); // Traces 3.142